Выполнение в Word повторяющейся задачи, требующей большого количества щелчков мыши или нажатий клавиш, каждый раз вызывает только раздражение. С помощью макроса можно объединить набор команд и заставить Word выполнять их по щелчку мыши или нажатию клавиши.
Включение макроса в Word 2010
Перейдите на вкладку ленты Разработчик. Если этой вкладки на вашей ленте нет, откройте окно Параметры Word и на вкладке Основные установите флажок на параметре Показывать вкладку «Разработчик» на ленте.
На вкладке “Разработчик” в группе команд “Код” нажмите кнопку “Начать запись”. Откроется диалоговое окно Запись макроса.
Для примера сделаем простую запись макроса, которая будет выполнять вставку текста в то место, где будет стоять курсор.
Запускаем запись макроса и в диалоговом окне пишем его название и описание, а так же выбираем доступ.
Нажмем ОК и начнется запись макроса.
Напечатаем текст и добавим ему цвет.
После чего нажмем “Остановить макрос”.
Для запуска макроса нужно нажать кнопку “Макросы” или комбинацию клавиш “Alt + F8”, так же макросу можно задать в личную комбинацию клавиш или вывести кнопку в меню.
Запустив окно “Макрос” выбираем нужный нам макрос и нажимаем выполнить, после чего он вставить в нужное нам место наш текст.
Создание макроса с помощью редактора Visual Basic for Applications (VBA).
Создадим простейший макрос, который будет позволять щелкать по гиперссылке в документе Word без нажатой клавиши Ctrl
Макросы для Word пишутся на языке программирования Visual Basic for Applications (VBA).
Макросы создаются в компоненте Word, который большинство пользователей никогда не видят, — в редакторе Visual Basic (VBE). Открыть редактор Visual Basic можно одним из указанных ниже способов.
- Нажмите сочетание клавиш ALT + F11
- Нажмите кнопку Visual Basic на вкладке Разработчик. Для этого откройте вкладку Файл и нажмите кнопку Параметры. В диалоговом окне Параметры Word нажмите кнопку Настройка ленты. В правой части диалогового окна выберите вкладку Разработчик. Нажмите кнопку ОК, чтобы вернуться к документу, а затем нажмите на вкладке Разработчик кнопку Visual Basic.
- Добавление команды Visual Basic на панель быстрого доступа.
Перед тем как приступить к работе с редактором Visual Basic, выберите в меню Сервис пункт Параметры. В диалоговом окне Параметры установите на вкладке Редактор все флажки.
В левом верхнем углу редактора Visual Basic расположено Окно проекта. В нем отображаются все файлы, открытые в Word в настоящий момент. Там должны отображаться файлы Normal (соответствующий шаблону Normal.dotm) и TheDocument (только что созданный файл).
На приведенном ниже рисунке показан проект TheDocument в окне проекта редактора Visual Basic.
В файле макросы хранятся в виде модулей. Чтобы добавить в файл модуль, выберите в окне проекта файл TheDocument. В меню Вставка выберите пункт Модуль. После добавлении модуля в файл этот модуль появится в окне проекта и в расположенном под ним окне свойств. В окне свойств модуль можно переименовать или оставить имя по умолчанию Module1.
Написание макроса
Большая белая область в правой части редактора Visual Basic предназначена для написания кода макроса. Если она не отображается, выберите в меню Вид пункт Код, чтобы вывести окно кода. Приложение Word автоматически вставит в начало кода оператор Option Explicit. Не удаляйте его.
Нам нужен макрос для переключения между двумя способами перехода по гиперссылке в Word. Он будет работать так же, как и другие кнопки, предназначенные для переключения между значениями параметра в Word. Кнопка Полужирный на вкладке "Главная", например, выделяет текст полужирным шрифтом, если он не был выделен, и отменяет полужирное начертание в противном случае.
Скопируйте и вставьте через буфер обмена приведенный ниже пример кода макроса в окно кода.
Sub ToggleHyperlinkCtrlClick()
Options.CtrlClickHyperlinkToOpen = Not Options.CtrlClickHyperlinkToOpen
End Sub
Это короткий макрос ToggleHyperlinkCtrlClick, состоящий только из одной строки кода. Эта строка означает "Изменить текущее значение параметра Word, определяющего необходимость использования сочетания CTRL + щелчок для перехода по гиперссылке, на противоположное (Not).
Тестирование макроса
Чтобы протестировать макрос, выполните указанные ниже действия.
- Разместите окна Word и редактора Visual Basic рядом друг с другом.
- Щелкните главное окно Word. Введите в документ http://google.com
- В редакторе Visual Basic щелкните в любом месте макроса. Чтобы запустить макрос, выберите в меню Выполнить команду Выполнить процедуру/форму пользователя или нажмите клавишу F5.
- Значение параметра, определяющего способ перехода по гиперссылке, изменится. Наведите указатель мыши на гиперссылку в главном окне Word и убедитесь, что подсказка изменилась.
- Чтобы переключить значение, запустите макрос повторно.
Макрос также можно запустить непосредственно в приложении Word. На вкладке Вид в группе Макросы нажмите кнопку Макросы. Откроется диалоговое окно Макрос, где в списке макросов будет и макрос ToggleHyperlinkCtrlClick. Чтобы запустить ваш макрос, щелкните его имя и нажмите кнопку Выполнить.
Создание на панели быстрого доступа кнопки для запуска макроса
Чтобы запускать макрос одним щелчком мыши, можно добавить кнопку на панель быстрого доступа. Для этого выполните указанные ниже действия.
Создание кнопки на панели быстрого доступа
- Щелкните панель быстрого доступа правой кнопкой мыши и выберите в контекстном меню команду Настройка панели быстрого доступа. В разделе Настройка панели быстрого доступа выберите в списке Выбрать команды из пункт Макросы. В списке "Настройка панели быстрого доступа" выберите файл MyWordTools.dotm. (Это необходимо, чтобы приложение Word сохранило кнопку на панели быстрого доступа в файле MyWordTools.dotm. Если этого не сделать, при копировании файла на другой компьютер кнопка отображаться не будет.) Выберите макрос ToggleHyperlinkCtrlClick и нажмите кнопку Добавить.
- Нажмите кнопку Изменить, чтобы выбрать символ и изменить имя на ToggleHyperlinkCtrlClick.
- Теперь макрос можно запустить в любой момент, нажав кнопку на панели быстрого доступа.
Макросы Word могут быть длинными, сложными и многофункциональными. Например, можно написать макрос для обращения к внешней базе данных, выполнения с полученными данными определенных вычислений и возврата результатов в Word. Также можно написать макрос Word для взаимодействия с Excel, PowerPoint или Outlook. В некоторых случаях и простые макросы могут оказаться полезными, позволяя сэкономить время.
Для форматирования текста больше подходят стили, чем макросы. Для изменения макета документа лучше создать новый шаблон. Кроме того, для выполнения поставленной задачи уже может существовать встроенная команда, которую можно добавить на панель быстрого доступа (при настройке панели быстрого доступа выберите в списке Выбрать команды из: пункт Все команды).
Как назначить сочетания клавиш для макросов
- Откройте диалоговое окно Параметры Word.
- Перейдите на закладку Настройка ленты и выбираем в командах: Макросы.
- Потом выбираем наш макрос и с низу жмем сочетание клавиш – настройки.
- В диалоговом окне настройки клавиатуры выбираем в категории макросы и в окне макросы выбираем нужный нам макрос.
- Щелкаем в новое сочетание клавиш и жмем на клавиатуре нужную нам комбинацию.
- Жмем назначить и ок
Примеры кодов:
Удаление лишних пробелов в тексте без использования диалогового окна “Найти и заменить”
Sub ReplaceMultiSpaces()
Dim oChar As Range
For Each oChar In ActiveDocument.Characters
If oChar.Text = " " Then
While oChar.Next(wdCharacter).Text = " "
oChar.Next(wdCharacter).Delete
Wend
End If
Next
End Sub
Расположение двух открытых документов Word рядом
Sub ArrangeDocWindows()
' ArrangeDocWindows Macro
' Arranges two document windows side by side vertically
Dim iMiddle As Integer
Dim iClientWid As Integer
Dim iClientHi As Integer
Dim iWin1 As Integer
Dim iWin2 As Integer
Dim sPrompt As String
Dim sWins As String
Dim i As Integer
iClientWid = Application.Width - 9
iMiddle = Fix((iClientWid) / 2)
iClientHi = Application.Height - 94
iWin1 = 1
iWin2 = 2
If Application.Windows.Count > 2 Then
For i = 1 To Application.Windows.Count
sPrompt = sPrompt & CStr(i) & " - " & Application.Windows(i).Caption & vbLf
Next
sWins = InputBox("Enter numbers of windows to arrange separated by space." & vbLf & sPrompt, _
"Choose windows", "1 2")
If sWins = "" Then
Exit Sub
End If
iWin1 = CInt(Left(sWins, InStr(sWins, " ") - 1))
iWin2 = CInt(Mid(sWins, InStr(sWins, " ") + 1))
End If
Application.Windows(iWin1).Activate
Application.Windows(iWin1).WindowState = wdWindowStateNormal
With ActiveWindow
.Left = 0
.Top = 0
.Height = iClientHi
.Width = iMiddle
End With
Application.Windows(iWin2).Activate
Application.Windows(iWin2).WindowState = wdWindowStateNormal
With ActiveWindow
.Left = iMiddle
.Top = 0
.Height = iClientHi
.Width = iClientWid - iMiddle
End With
End Sub
Обратите внимание, что если у вас будет открыто только одно окно, то после нажатия этой кнопки может появиться окно с сообщением редактора кода Visual Basic об ошибке. Закройте его нажав на кнопку End. А в следующий раз будьте внимательны.
Преобразование гиперссылки в документе Word в обычный текст
Sub RemoveHyperlinks()
While ActiveDocument.Hyperlinks.Count > 0
ActiveDocument.Hyperlinks(1).Delete
Wend
Application.Options.AutoFormatAsYouTypeReplaceHyperlinks = False
End Sub
Изменения цвета заглавных букв в тексте
Sub colorAllBig()
Dim fChar As Range
Dim seltext As Range
Dim i As Long
Set seltext = Selection.Range
If Selection.Type = wdSelectionIP Then
MsgBox "Выделите текст"
Else
For Each fChar In seltext.Words
For i = 1 To fChar.Characters.Count
If fChar.Characters(i).Case = wdUpperCase Then
fChar.Characters(i).Font.Color = wdColorRed
Else
fChar.Characters(i).Font.Color = wdColorBlack
End If
Next i
Next fChar
End If
End Sub